Comment numéroter (incrémenter) automatiquement ses numéros de factures ou d’autres clefs ?

Cet arti­cle cou­vre les 15 pre­mières min­utes de la for­ma­tion sur les tableaux que je donne ici. 

Cette ques­tion des numéros de fac­ture est peut-être la plus anci­enne d’Ex­cel, mais elle est tou­jours par­mi les plus demandés ! Il existe de nom­breux répons­es pos­si­bles, mais voici un code un peu plus poussé qui présente beau­coup d’avantages : 

  • Pas d’u­til­i­sa­tion de la solu­tion avec xlUp qui peut génér­er des erreurs si des don­nées sont entrées en dessous de la table ou si on dépasse un cer­tain nom­bre de lignes — en fonc­tion du code trou­vé sur internet.
  • Ges­tion du cas d’une table vide.
  • Pos­si­bil­ité d’a­jouter très rapi­de­ment plusieurs lignes au lieu d’une seule.
  • Posi­tion­nement direct sur la dernière ligne après l’ajout.
  • Avec un tableau, les for­mules et les for­mats sont recopiés automa­tique­ment vers le bas. 

Téléchargez le fichier.

Installation en vidéo

Pour un nouveau fichier

  • Utilisez un tableau struc­turé pour stock­er vos fac­tures : Accueil, Met­tre sous forme de tableau
  • Renom­mez le tableau struc­turé, ici T_Data
  • Suiv­re la suite des étapes

Pour un fichier existant contenant déjà un tableau structuré

  • Copiez le code ci-dessous dans un nou­veau mod­ule : ALT+F11, Inser­tion — Module
  • Revenez sur Excel, puis ajoutez un bou­ton.
    Vous pou­vez utilis­er les nou­veautés d’Ex­cel avec Insertion :
  • Associez‑y ce code via un clic droit sur l’icône, affecter une macro et choisir AjouterUneLigne.

Explication du code en vidéo

Le code

Option Explicit
Sub AjouterUneLigne()
    AjouterNLignes loData, 1, 1
    GoToDerniereLigneDuTableau loData, 10
End Sub
Sub Ajouter5Lignes()
    AjouterNLignes loData, 5, 1
    GoToDerniereLigneDuTableau loData, 10
End Sub
Private Sub GoToDerniereLigneDuTableau(loTable As ListObject, nLignesVisibles As Long)
    Dim rLastCell As Range
    Set rLastCell = loTable.DataBodyRange.Resize(1, 1).Offset(loTable.DataBodyRange.Rows.Count - 1)
    On Error Resume Next 'au cas ou on est en haut de la feuille
    Application.Goto rLastCell.Offset(-nLignesVisibles, 1), True
    On Error GoTo 0
    Application.Goto rLastCell, False
End Sub
Private Sub AjouterNLignes(loTable As ListObject, nRow As Long, lColKey As Long)
    'on aurait pu faire une boucle ajoutant nRow lignes,
    'mais le redimensionnement - resize - est (beaucoup) plus rapide que l'ajout
    'd'une ligne à la suite.
    Dim lMax As Long
    Dim lNbRowsStart As Long
    'aucune donnee, on demarre la numerotation a 1
    If loTable.DataBodyRange Is Nothing Then
        loTable.ListRows.Add (1)
        If nRow <> 1 Then loTable.Resize loTable.Range.Resize(loTable.Range.Rows.Count + nRow - 1)
        loTable.DataBodyRange.Resize(, 1).Offset(, lColKey - 1).Value = _
            fctSequence(nRow, 1, 1, 1)
            'Application.WorksheetFunction.Sequence(nRow, 1)'unqiuement en excel 365
    Else
        lNbRowsStart = loTable.DataBodyRange.Rows.Count
        lMax = Application.WorksheetFunction.Max(loTable.DataBodyRange.Columns(lColKey))
        loTable.Resize loTable.Range.Resize(loTable.Range.Rows.Count + nRow)
        loTable.DataBodyRange.Resize(nRow, 1).Offset(lNbRowsStart, lColKey - 1).Value = _
            fctSequence(nRow, 1, lMax + 1, 1)
        'Application.WorksheetFunction.Sequence(nRow, 1, lMax + 1) 'si vous etes en excel 365
    End If
End Sub
Private Function fctSequence(lRow As Long, lCol As Long, lStart As Long, lStep As Long)
    Dim arrSequence As Variant
    ReDim arrSequence(1 To lRow, 1 To lCol) As Variant
    Dim lRowLoop As Long, lColLoop As Long
    Dim lValue As Long
    lValue = lStart
    For lRowLoop = 1 To lRow
        For lColLoop = 1 To lCol
            arrSequence(lRowLoop, lColLoop) = lValue
            lValue = lValue + lStep
        Next
    Next
    fctSequence = arrSequence
End Function
Private Function loData() As ListObject
    'Set loData = wksData.ListObjects("T_Data") 'au cas où l'on veut faire fonctionner la macro a partir d'une autre feuille
    Set loData = ActiveSheet.ListObjects(1)
End Function
Pour marque-pages : Permaliens.

Laisser un commentaire

Votre adresse e-mail ne sera pas publiée. Les champs obligatoires sont indiqués avec *

Ce site utilise Akismet pour réduire les indésirables. En savoir plus sur comment les données de vos commentaires sont utilisées.