Comparer deux plages en une seule formule

Voici la for­mule en ver­sion simple : 

=SI(A1:D4=G1:J4;"";"Erreur")

Et en ver­sion un peu plus complexe : 

=LET(plage1;A1:D4;plage2;G1:J4;"Erreur(s) possible(s) en "  &
JOINDRE.TEXTE("/";VRAI;SI(plage1=plage2;"";SUBSTITUE(ADRESSE(1;COLONNE(plage1);4);"1";"") & LIGNE(plage1))))

Et suite aux com­men­taires, en ten­ant compte de la sit­u­a­tion où il n’y a pas d’er­reurs, et en ajoutant les valeurs entre parenthèses :

=LET(plage1;A1:D4;plage2;G1:J4;
SI(SOMME(SI(plage1=plage2;0;1))=0;"Aucune erreur";
"Erreur(s) possible(s) en " &
JOINDRE.TEXTE("/";VRAI;SI(plage1=plage2;"";
SUBSTITUE(ADRESSE(1;COLONNE(plage1);4);"1";"") & LIGNE(plage1)&"('"&
plage1& "' vs. '" & plage2 & "')"
))))

Vous pou­vez télécharg­er ici le fichi­er exem­ple, et voir la vidéo attachée ! 

Amusez-vous bien et n’hésitez pas à don­ner vos commentaires 🙂

Pour marque-pages : Permaliens.

4 réponses à Comparer deux plages en une seule formule

  1. Dominique HANDELSMAN dit :

    Bon­jour.
    une bonne alter­na­tive à =SI(A1:D4=G1:J4;””;“Erreur”) est =SI(A1:D4=G1:J4;0;1).
    ça per­met de compter les erreurs.

  2. ptck dit :

    Bon­jour
    et si on voulait met­tre aucune erreur au lieu de
    Erreur(s) possible(s) en
    quand les 2 tableaux n’ont pas d’erreur
    Ptck

  3. GM dit :

    Hel­lo,
    En pous­sant l’idée de Dominique :
    =LET(plage1;A1:D4;plage2;G1:J4;
    SI(SOMME(SI(A1:D4=G1:J4;0;1))=0;“Aucune erreur”;
    “Erreur(s) possible(s) en ” &
    JOINDRE.TEXTE(“/”;VRAI;SI(plage1=plage2;””;
    SUBSTITUE(ADRESSE(1;COLONNE(plage1);4);“1”;“”) & LIGNE(plage1)&”(‘”&
    plage1& “ ‘ vs. ’ ” & plage2 & “’)”
    ))))

  4. GM dit :

    Atten­tion aux guillemets, j’ai l’im­pres­sion qu’ils passent mal dans les commentaires.

Laisser un commentaire

Votre adresse e-mail ne sera pas publiée. Les champs obligatoires sont indiqués avec *

Ce site utilise Akismet pour réduire les indésirables. En savoir plus sur comment les données de vos commentaires sont utilisées.